Files
@ d6faa5ffcedf
Branch filter:
Location: MD/arcos/fish90/src/hst_procs.f90
d6faa5ffcedf
67.4 KiB
text/x-fortran
install arcos
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116 1117 1118 1119 1120 1121 1122 1123 1124 1125 1126 1127 1128 1129 1130 1131 1132 1133 1134 1135 1136 1137 1138 1139 1140 1141 1142 1143 1144 1145 1146 1147 1148 1149 1150 1151 1152 1153 1154 1155 1156 1157 1158 1159 1160 1161 1162 1163 1164 1165 1166 1167 1168 1169 1170 1171 1172 1173 1174 1175 1176 1177 1178 1179 1180 1181 1182 1183 1184 1185 1186 1187 1188 1189 1190 1191 1192 1193 1194 1195 1196 1197 1198 1199 1200 1201 1202 1203 1204 1205 1206 1207 1208 1209 1210 1211 1212 1213 1214 1215 1216 1217 1218 1219 1220 1221 1222 1223 1224 1225 1226 1227 1228 1229 1230 1231 1232 1233 1234 1235 1236 1237 1238 1239 1240 1241 1242 1243 1244 1245 1246 1247 1248 1249 1250 1251 1252 1253 1254 1255 1256 1257 1258 1259 1260 1261 1262 1263 1264 1265 1266 1267 1268 1269 1270 1271 1272 1273 1274 1275 1276 1277 1278 1279 1280 1281 1282 1283 1284 1285 1286 1287 1288 1289 1290 1291 1292 1293 1294 1295 1296 1297 1298 1299 1300 1301 1302 1303 1304 1305 1306 1307 1308 1309 1310 1311 1312 1313 1314 1315 1316 1317 1318 1319 1320 1321 1322 1323 1324 1325 1326 1327 1328 1329 1330 1331 1332 1333 1334 1335 1336 1337 1338 1339 1340 1341 1342 1343 1344 1345 1346 1347 1348 1349 1350 1351 1352 1353 1354 1355 1356 1357 1358 1359 1360 1361 1362 1363 1364 1365 1366 1367 1368 1369 1370 1371 1372 1373 1374 1375 1376 1377 1378 1379 1380 1381 1382 1383 1384 1385 1386 1387 1388 1389 1390 1391 1392 1393 1394 1395 1396 1397 1398 1399 1400 1401 1402 1403 1404 1405 1406 1407 1408 1409 1410 1411 1412 1413 1414 1415 1416 1417 1418 1419 1420 1421 1422 1423 1424 1425 1426 1427 1428 1429 1430 1431 1432 1433 1434 1435 1436 1437 1438 1439 1440 1441 1442 1443 1444 1445 1446 1447 1448 1449 1450 1451 1452 1453 1454 1455 1456 1457 1458 1459 1460 1461 1462 1463 1464 1465 1466 1467 1468 1469 1470 1471 1472 1473 1474 1475 1476 1477 1478 1479 1480 1481 1482 1483 1484 1485 1486 1487 1488 1489 1490 1491 1492 1493 1494 1495 1496 1497 1498 1499 1500 1501 1502 1503 1504 1505 1506 1507 1508 1509 1510 1511 1512 1513 1514 1515 1516 1517 1518 1519 1520 1521 1522 1523 1524 1525 1526 1527 1528 1529 1530 1531 1532 1533 1534 1535 1536 1537 1538 1539 1540 1541 1542 1543 1544 1545 1546 1547 1548 1549 1550 1551 1552 1553 1554 1555 1556 1557 1558 1559 1560 1561 1562 1563 1564 1565 1566 1567 1568 1569 1570 1571 1572 1573 1574 1575 1576 1577 1578 1579 1580 1581 1582 1583 1584 1585 1586 1587 1588 1589 1590 1591 1592 1593 1594 1595 1596 1597 1598 1599 1600 1601 1602 1603 1604 1605 1606 1607 1608 1609 1610 1611 1612 1613 1614 1615 1616 1617 1618 1619 1620 1621 1622 1623 1624 1625 1626 1627 1628 1629 1630 1631 1632 1633 1634 1635 1636 1637 1638 1639 1640 1641 1642 1643 1644 1645 1646 1647 1648 1649 1650 | !
! file hstcrt.f
!
! . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
! . .
! . copyright (c) 2004 by UCAR .
! . .
! . UNIVERSITY CORPORATION for ATMOSPHERIC RESEARCH .
! . .
! . all rights reserved .
! . .
! . .
! . FISHPACK version 5.0 .
! . .
! . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
!
! * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
! * *
! * F I S H P A C K *
! * *
! * *
! * A PACKAGE OF FORTRAN SUBPROGRAMS FOR THE SOLUTION OF *
! * *
! * SEPARABLE ELLIPTIC PARTIAL DIFFERENTIAL EQUATIONS *
! * *
! * (Version 5.0 , JUNE 2004) *
! * *
! * BY *
! * *
! * JOHN ADAMS, PAUL SWARZTRAUBER AND ROLAND SWEET *
! * *
! * OF *
! * *
! * THE NATIONAL CENTER FOR ATMOSPHERIC RESEARCH *
! * *
! * BOULDER, COLORADO (80307) U.S.A. *
! * *
! * WHICH IS SPONSORED BY *
! * *
! * THE NATIONAL SCIENCE FOUNDATION *
! * *
! * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
!
! SUBROUTINE HSTCRT (A,B,M,MBDCND,BDA,BDB,C,D,N,NBDCND,BDC,BDD,
! + ELMBDA,F,IDIMF,PERTRB,IERROR)
!
! DIMENSION OF BDA(N),BDB(N),BDC(M),BDD(M),F(IDIMF,N)
! ARGUMENTS
!
! LATEST REVISION June 2004
!
! PURPOSE SOLVES THE STANDARD FIVE-POINT FINITE
! DIFFERENCE APPROXIMATION TO THE HELMHOLTZ
! EQUATION
! (D/DX)(DU/DX) + (D/DY)(DU/DY) + LAMBDA*U
! = F(X,Y)
! ON A STAGGERED GRID IN CARTESIAN COORDINATES.
!
! USAGE CALL HSTCRT (A,B,M,MBDCND,BDA,BDB,C,D
! N,NBDCND,BDC,BDD,ELMBDA,
! F,IDIMF,PERTRB,IERROR)
!
! ARGUMENTS
! ON INPUT
!
! A,B
! THE RANGE OF X, I.E. A .LE. X .LE. B.
! A MUST BE LESS THAN B.
!
! M
! THE NUMBER OF GRID POINTS IN THE
! INTERVAL (A,B). THE GRID POINTS
! IN THE X-DIRECTION ARE GIVEN BY
! X(I) = A + (I-0.5)DX FOR I=1,2,...,M
! WHERE DX =(B-A)/M. M MUST BE GREATER
! THAN 2.
!
! MBDCND
! INDICATES THE TYPE OF BOUNDARY CONDITIONS
! AT X = A AND X = B.
!
! = 0 IF THE SOLUTION IS PERIODIC IN X,
! U(M+I,J) = U(I,J).
!
! = 1 IF THE SOLUTION IS SPECIFIED AT
! X = A AND X = B.
!
! = 2 IF THE SOLUTION IS SPECIFIED AT
! X = A AND THE DERIVATIVE
! OF THE SOLUTION WITH RESPECT TO X
! IS SPECIFIED AT X = B.
!
! = 3 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO X IS SPECIFIED
! AT X = A AND X = B.
!
! = 4 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO X IS SPECIFIED
! AT X = A AND THE SOLUTION IS
! SPECIFIED AT X = B.
!
! BDA
! A ONE-DIMENSIONAL ARRAY OF LENGTH N
! THAT SPECIFIES THE BOUNDARY VALUES
! (IF ANY) OF THE SOLUTION AT X = A.
!
! WHEN MBDCND = 1 OR 2,
! BDA(J) = U(A,Y(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 3 OR 4,
! BDA(J) = (D/DX)U(A,Y(J)) , J=1,2,...,N.
!
! BDB
! A ONE-DIMENSIONAL ARRAY OF LENGTH N
! THAT SPECIFIES THE BOUNDARY VALUES
! OF THE SOLUTION AT X = B.
!
! WHEN MBDCND = 1 OR 4
! BDB(J) = U(B,Y(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 2 OR 3
! BDB(J) = (D/DX)U(B,Y(J)) , J=1,2,...,N.
!
! C,D
! THE RANGE OF Y, I.E. C .LE. Y .LE. D.
! C MUST BE LESS THAN D.
!
!
! N
! THE NUMBER OF UNKNOWNS IN THE INTERVAL
! (C,D). THE UNKNOWNS IN THE Y-DIRECTION
! ARE GIVEN BY Y(J) = C + (J-0.5)DY,
! J=1,2,...,N, WHERE DY = (D-C)/N.
! N MUST BE GREATER THAN 2.
!
! NBDCND
! INDICATES THE TYPE OF BOUNDARY CONDITIONS
! AT Y = C AND Y = D.
!
!
! = 0 IF THE SOLUTION IS PERIODIC IN Y, I.E.
! U(I,J) = U(I,N+J).
!
! = 1 IF THE SOLUTION IS SPECIFIED AT Y = C
! AND Y = D.
!
! = 2 IF THE SOLUTION IS SPECIFIED AT Y = C
! AND THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO Y IS SPECIFIED AT
! Y = D.
!
! = 3 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO Y IS SPECIFIED AT
! Y = C AND Y = D.
!
! = 4 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO Y IS SPECIFIED AT
! Y = C AND THE SOLUTION IS SPECIFIED
! AT Y = D.
!
! BDC
! A ONE DIMENSIONAL ARRAY OF LENGTH M THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT Y = C.
!
! WHEN NBDCND = 1 OR 2,
! BDC(I) = U(X(I),C) , I=1,2,...,M.
!
! WHEN NBDCND = 3 OR 4,
! BDC(I) = (D/DY)U(X(I),C), I=1,2,...,M.
!
! WHEN NBDCND = 0, BDC IS A DUMMY VARIABLE.
!
! BDD
! A ONE-DIMENSIONAL ARRAY OF LENGTH M THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT Y = D.
!
! WHEN NBDCND = 1 OR 4,
! BDD(I) = U(X(I),D) , I=1,2,...,M.
!
! WHEN NBDCND = 2 OR 3,
! BDD(I) = (D/DY)U(X(I),D) , I=1,2,...,M.
!
! WHEN NBDCND = 0, BDD IS A DUMMY VARIABLE.
!
! ELMBDA
! THE CONSTANT LAMBDA IN THE HELMHOLTZ
! EQUATION. IF LAMBDA IS GREATER THAN 0,
! A SOLUTION MAY NOT EXIST. HOWEVER,
! HSTCRT WILL ATTEMPT TO FIND A SOLUTION.
!
! F
! A TWO-DIMENSIONAL ARRAY THAT SPECIFIES
! THE VALUES OF THE RIGHT SIDE OF THE
! HELMHOLTZ EQUATION. FOR I=1,2,...,M
! AND J=1,2,...,N
!
! F(I,J) = F(X(I),Y(J)) .
!
! F MUST BE DIMENSIONED AT LEAST M X N.
!
! IDIMF
! THE ROW (OR FIRST) DIMENSION OF THE ARRAY
! F AS IT APPEARS IN THE PROGRAM CALLING
! HSTCRT. THIS PARAMETER IS USED TO SPECIFY
! THE VARIABLE DIMENSION OF F.
! IDIMF MUST BE AT LEAST M.
!
!
! ON OUTPUT F
! CONTAINS THE SOLUTION U(I,J) OF THE FINITE
! DIFFERENCE APPROXIMATION FOR THE GRID POINT
! (X(I),Y(J)) FOR I=1,2,...,M, J=1,2,...,N.
!
! PERTRB
! IF A COMBINATION OF PERIODIC OR DERIVATIVE
! BOUNDARY CONDITIONS IS SPECIFIED FOR A
! POISSON EQUATION (LAMBDA = 0), A SOLUTION
! MAY NOT EXIST. PERTRB IS A CONSTANT,
! CALCULATED AND SUBTRACTED FROM F, WHICH
! ENSURES THAT A SOLUTION EXISTS. HSTCRT
! THEN COMPUTES THIS SOLUTION, WHICH IS A
! LEAST SQUARES SOLUTION TO THE ORIGINAL
! APPROXIMATION. THIS SOLUTION PLUS ANY
! CONSTANT IS ALSO A SOLUTION; HENCE, THE
! SOLUTION IS NOT UNIQUE. THE VALUE OF
! PERTRB SHOULD BE SMALL COMPARED TO THE
! RIGHT SIDE F. OTHERWISE, A SOLUTION IS
! OBTAINED TO AN ESSENTIALLY DIFFERENT PROBLEM.
! THIS COMPARISON SHOULD ALWAYS BE MADE TO
! INSURE THAT A MEANINGFUL SOLUTION HAS BEEN
! OBTAINED.
!
! IERROR
! AN ERROR FLAG THAT INDICATES INVALID INPUT
! PARAMETERS. EXCEPT TO NUMBERS 0 AND 6,
! A SOLUTION IS NOT ATTEMPTED.
!
! = 0 NO ERROR
!
! = 1 A .GE. B
!
! = 2 MBDCND .LT. 0 OR MBDCND .GT. 4
!
! = 3 C .GE. D
!
! = 4 N .LE. 2
!
! = 5 NBDCND .LT. 0 OR NBDCND .GT. 4
!
! = 6 LAMBDA .GT. 0
!
! = 7 IDIMF .LT. M
!
! = 8 M .LE. 2
!
! SINCE THIS IS THE ONLY MEANS OF INDICATING
! A POSSIBLY INCORRECT CALL TO HSTCRT, THE
! USER SHOULD TEST IERROR AFTER THE CALL.
!
! = 20 If the dynamic allocation of real and
! complex work space required for solution
! fails (for example if N,M are too large
! for your computer)
!
!
! I/O NONE
!
! PRECISION SINGLE
!
! REQUIRED LIBRARY fish.f,comf.f,genbun.f,gnbnaux.f,poistg.f
! FILES
!
! LANGUAGE FORTRAN 90
!
! HISTORY WRITTEN BY ROLAND SWEET AT NCAR IN 1977.
! RELEASED ON NCAR'S PUBLIC SOFTWARE LIBRARIES
! IN JANUARY 1980.
! Revised in June 2004 by John Adams using
! Fortran 90 dynamically allocated work space.
!
! PORTABILITY FORTRAN 90
!
! ALGORITHM THIS SUBROUTINE DEFINES THE FINITE-DIFFERENCE
! EQUATIONS, INCORPORATES BOUNDARY DATA, ADJUSTS
! THE RIGHT SIDE WHEN THE SYSTEM IS SINGULAR
! AND CALLS EITHER POISTG OR GENBUN WHICH SOLVES
! THE LINEAR SYSTEM OF EQUATIONS.
!
! TIMING FOR LARGE M AND N, THE OPERATION COUNT
! IS ROUGHLY PROPORTIONAL TO M*N*LOG2(N).
!
! ACCURACY THE SOLUTION PROCESS EMPLOYED RESULTS IN A
! LOSS OF NO MORE THAN FOUR SIGNIFICANT DIGITS
! FOR N AND M AS LARGE AS 64. MORE DETAILED
! INFORMATION ABOUT ACCURACY CAN BE FOUND IN
! THE DOCUMENTATION FOR PACKAGE POISTG WHICH
! SOLVES THE FINITE DIFFERENCE EQUATIONS.
!
! REFERENCES U. SCHUMANN AND R. SWEET,"A DIRECT METHOD
! FOR THE SOLUTION OF POISSON'S EQUATION WITH
! BOUNDARY CONDITIONS ON A STAGGERED GRID OF
! ARBITRARY SIZE," J. COMP. PHYS. 20(1976),
! PP. 171-182.
!***********************************************************************
SUBROUTINE HSTCRT(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, matF, IDIMF, PERTRB, IERROR)
USE fish
implicit none
DOUBLE PRECISION, PARAMETER :: ZERO = 0.0D0, HALF = 0.5D0, &
ONE = 1.0D0, TWO = 2.0D0, &
FOUR = 4.0D0
!-----------------------------------------------
! D u m m y A r g u m e n t s
!-----------------------------------------------
INTEGER,INTENT(IN) :: M,MBDCND,N,NBDCND,IDIMF
INTEGER,INTENT(OUT) :: IERROR
DOUBLE PRECISION,INTENT(IN) :: A,B,C,D,ELMBDA
DOUBLE PRECISION,INTENT(OUT) :: PERTRB
DOUBLE PRECISION,DIMENSION(N),INTENT(IN) :: vecBDA,vecBDB
DOUBLE PRECISION,DIMENSION(M),INTENT(IN) :: vecBDC,vecBDD
DOUBLE PRECISION,DIMENSION(IDIMF,N),INTENT(INOUT) :: matF
!-----------------------------------------------
! Allocatable arrays
!-----------------------------------------------
DOUBLE PRECISION,DIMENSION(:),ALLOCATABLE :: work
!-----------------------------------------------
! L o c a l V a r i a b l e s
!-----------------------------------------------
INTEGER :: irwk, istatus
! JANNIS: add interface
interface
SUBROUTINE HSTCRTT(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, matF, IDIMF, PERTRB, IERROR, vecW, IW)
INTEGER,INTENT(IN) :: M,MBDCND,N,NBDCND,IDIMF,IW
INTEGER,INTENT(OUT) :: IERROR
DOUBLE PRECISION,INTENT(IN) :: A,B,C,D,ELMBDA
DOUBLE PRECISION,INTENT(OUT) :: PERTRB
DOUBLE PRECISION,DIMENSION(N),INTENT(IN) :: vecBDA,vecBDB
DOUBLE PRECISION,DIMENSION(M),INTENT(IN) :: vecBDC,vecBDD
DOUBLE PRECISION,DIMENSION(IDIMF,N),INTENT(INOUT) :: matF
DOUBLE PRECISION,DIMENSION(IW),INTENT(INOUT) :: vecW
end subroutine HSTCRTT
end interface
!-----------------------------------------------
!
! CHECK FOR INVALID PARAMETERS.
!
IERROR = 0
IF (A >= B) IERROR = 1
IF (MBDCND<0 .OR. MBDCND>4) IERROR = 2
IF (C >= D) IERROR = 3
IF (N <= 2) IERROR = 4
IF (NBDCND<0 .OR. NBDCND>4) IERROR = 5
IF (IDIMF < M) IERROR = 7
IF (M <= 2) IERROR = 8
IF (IERROR /= 0) RETURN
!C! write(*,*) 'hstcrt: vecBDC:',vecBDC(1:size(vecBDC))
!C! write(*,*) 'hstcrt: BDD:',BDD(:)
!C! write(*,*) 'hstcrt: ELMBDA:',ELMBDA
!C! write(*,*) 'hstcrt: matF:',matF(1:IDIMF,:)
!C! write(*,*) 'hstcrt: IDIMF:',IDIMF
! compute and allocate required real work space
CALL GEN_SPACE (N, M, IRWK)
irwk = irwk + 3*M
allocate(work(irwK),STAT=istatus)
!@! write(*,*) 'HSTCRT: allocate work(irwk); irwk=',irwk
! return if allocation failed (e.g., if n,m are too large)
IF (istatus > 0) THEN
write(*,*) 'HSTCRT: error allocate work(irwk); irwk=',irwk
RETURN
END IF
! check that allocation was successful
call hstcrtt(a,b,m,mbdcnd,vecbda,vecbdb,c,d,n,nbdcnd, &
vecbdc,vecbdd,elmbda,matf,idimf,pertrb,ierror, &
work,size(work))
!
!@! write(*,*) 'HSTCRT: deallocate work(irwk); irwk=',irwk
deallocate(work,STAT=istatus)
IF (istatus > 0) THEN
write(*,*) 'HSTCRT: error deallocate work'
RETURN
END IF
!
END SUBROUTINE HSTCRT
SUBROUTINE HSTCRTT(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, matF, IDIMF, PERTRB, &
IERROR, vecW, IW)
! USE genbunal
! USE poisson
implicit none
DOUBLE PRECISION, PARAMETER :: ZERO = 0.0D0, HALF = 0.5D0, &
ONE = 1.0D0, TWO = 2.0D0, &
FOUR = 4.0D0
!-----------------------------------------------
! D u m m y A r g u m e n t s
!-----------------------------------------------
INTEGER,INTENT(IN) :: M,MBDCND,N,NBDCND,IDIMF,IW
INTEGER,INTENT(OUT) :: IERROR
DOUBLE PRECISION,INTENT(IN) :: A,B,C,D,ELMBDA
DOUBLE PRECISION,INTENT(OUT) :: PERTRB
DOUBLE PRECISION,DIMENSION(N),INTENT(IN) :: vecBDA,vecBDB
DOUBLE PRECISION,DIMENSION(M),INTENT(IN) :: vecBDC,vecBDD
DOUBLE PRECISION,DIMENSION(IDIMF,N),INTENT(INOUT) :: matF
DOUBLE PRECISION,DIMENSION(IW),INTENT(INOUT) :: vecW
!-----------------------------------------------
! L o c a l V a r i a b l e s
!-----------------------------------------------
INTEGER :: NPEROD, MPEROD, NP, MP, ID2, ID3, ID4, &
J, IERR1, IW2
DOUBLE PRECISION :: DELTAX,TWDELX,DELXSQ,DELTAY,TWDELY,DELYSQ,TWDYSQ,S,ST2
!-----------------------------------------------
NPEROD = NBDCND
MPEROD = 0
IF (MBDCND > 0) MPEROD = 1
DELTAX = (B - A)/DBLE(M)
TWDELX = ONE/DELTAX
DELXSQ = TWO/DELTAX**2
DELTAY = (D - C)/DBLE(N)
TWDELY = ONE/DELTAY
DELYSQ = DELTAY**2
TWDYSQ = TWO/DELYSQ
NP = NBDCND + 1
MP = MBDCND + 1
!
! DEFINE THE A,B,C COEFFICIENTS IN W-ARRAY.
!
ID2 = M
ID3 = ID2 + M
ID4 = ID3 + M
S = (DELTAY/DELTAX)**2
ST2 = TWO*S
vecW(:M) = S
vecW(ID2+1:M+ID2) = (-ST2) + ELMBDA*DELYSQ
vecW(ID3+1:M+ID3) = S
!
! ENTER BOUNDARY DATA FOR X-BOUNDARIES.
!
GO TO (111,102,102,104,104) MP
102 CONTINUE
matF(1,:N) = matF(1,:N) - vecBDA(:N)*DELXSQ
vecW(ID2+1) = vecW(ID2+1) - vecW(1)
GO TO 106
104 CONTINUE
matF(1,:N) = matF(1,:N) + vecBDA(:N)*TWDELX
vecW(ID2+1) = vecW(ID2+1) + vecW(1)
106 CONTINUE
GO TO (111,107,109,109,107) MP
107 CONTINUE
matF(M,:N) = matF(M,:N) - vecBDB(:N)*DELXSQ
vecW(ID3) = vecW(ID3) - vecW(1)
GO TO 111
109 CONTINUE
matF(M,:N) = matF(M,:N) - vecBDB(:N)*TWDELX
vecW(ID3) = vecW(ID3) + vecW(1)
111 CONTINUE
GO TO (121,112,112,114,114) NP
112 CONTINUE
matF(:M,1) = matF(:M,1) - vecBDC(:M)*TWDYSQ
GO TO 116
114 CONTINUE
matF(:M,1) = matF(:M,1) + vecBDC(:M)*TWDELY
116 CONTINUE
GO TO (121,117,119,119,117) NP
117 CONTINUE
matF(:M,N) = matF(:M,N) - vecBDD(:M)*TWDYSQ
GO TO 121
119 CONTINUE
matF(:M,N) = matF(:M,N) - vecBDD(:M)*TWDELY
121 CONTINUE
matF(:M,:N) = matF(:M,:N)*DELYSQ
IF (MPEROD /= 0) THEN
vecW(1) = ZERO
vecW(ID4) = ZERO
ENDIF
PERTRB = ZERO
IF (ELMBDA >= ZERO) THEN
IF (ELMBDA /= ZERO) THEN
IERROR = 6
ELSE
GO TO (127,133,133,127,133) MP
127 CONTINUE
GO TO (128,133,133,128,133) NP
!
! FOR SINGULAR PROBLEMS MUST ADJUST DATA TO INSURE THAT A SOLUTION
! WILL EXIST.
!
128 CONTINUE
S = ZERO
DO J = 1, N
S = S + SUM(matF(:M,J))
END DO
PERTRB = S/DBLE(M*N)
matF(:M,:N) = matF(:M,:N) - PERTRB
PERTRB = PERTRB/DELYSQ
!
! SOLVE THE EQUATION.
!
ENDIF
ENDIF
133 CONTINUE
IERR1 = 0
! Workarray splitted into parts of length M and IW
IW2 = size(vecW)-ID4
IF (NPEROD /= 0) THEN
CALL POISTGG (NPEROD, N, MPEROD, M, vecW(1:M), vecW(ID2+1:ID2+M), &
vecW(ID3+1:ID3+M),IDIMF, matF, IERR1, vecW(ID4+1:),IW2)
ELSE
CALL GENBUNN (NPEROD, N, MPEROD, M, vecW(1:M), vecW(ID2+1:ID2+M), &
vecW(ID3+1:ID3+M), IDIMF, matF, IERR1, vecW(ID4+1:),IW2)
ENDIF
!
! REVISION HISTORY---
!
! SEPTEMBER 1973 VERSION 1
! APRIL 1976 VERSION 2
! JANUARY 1978 VERSION 3
! DECEMBER 1979 VERSION 3.1
! FEBRUARY 1985 DOCUMENTATION UPGRADE
! NOVEMBER 1988 VERSION 3.2, FORTRAN 77 CHANGES
! June 2004 Version 5.0, Fortran 90 changes
!-----------------------------------------------------------------------
END SUBROUTINE HSTCRTT
! file hstcyl.f
!
! . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
! . .
! . copyright (c) 2004 by UCAR .
! . .
! . UNIVERSITY CORPORATION for ATMOSPHERIC RESEARCH .
! . .
! . all rights reserved .
! . .
! . .
! . FISHPACK version 5.0 .
! . .
! . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
!
! * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
! * *
! * F I S H P A C K *
! * *
! * *
! * A PACKAGE OF FORTRAN SUBPROGRAMS FOR THE SOLUTION OF *
! * *
! * SEPARABLE ELLIPTIC PARTIAL DIFFERENTIAL EQUATIONS *
! * *
! * (Version 5.0 , JUNE 2004) *
! * *
! * BY *
! * *
! * JOHN ADAMS, PAUL SWARZTRAUBER AND ROLAND SWEET *
! * *
! * OF *
! * *
! * THE NATIONAL CENTER FOR ATMOSPHERIC RESEARCH *
! * *
! * BOULDER, COLORADO (80307) U.S.A. *
! * *
! * WHICH IS SPONSORED BY *
! * *
! * THE NATIONAL SCIENCE FOUNDATION *
! * *
! * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
!
! SUBROUTINE HSTCYL (A,B,M,MBDCND,BDA,BDB,C,D,N,NBDCND,BDC,BDD,
! + ELMBDA,F,IDIMF,PERTRB,IERROR)
!
! DIMENSION OF BDA(N),BDB(N),BDC(M),BDD(M),F(IDIMF,N)
! ARGUMENTS
!
! LATEST REVISION June 2004
!
! PURPOSE SOLVES THE STANDARD FIVE-POINT FINITE
! DIFFERENCE APPROXIMATION ON A STAGGERED
! GRID TO THE MODIFIED HELMHOLTZ EQUATION
! IN CYLINDRICAL COORDINATES. THIS EQUATION
!
! (1/R)(D/DR)(R(DU/DR)) + (D/DZ)(DU/DZ)
!
! + LAMBDA*(1/R**2)*U = F(R,Z)
!
! IS A TWO-DIMENSIONAL MODIFIED HELMHOLTZ
! EQUATION RESULTING FROM THE FOURIER TRANSFORM
! OF A THREE-DIMENSIONAL POISSON EQUATION.
!
! USAGE CALL HSTCYL (A,B,M,MBDCND,BDA,BDB,C,D,N,
! NBDCND,BDC,BDD,ELMBDA,F,IDIMF,
! PERTRB,IERROR)
!
! ARGUMENTS
! ON INPUT A,B
!
! THE RANGE OF R, I.E. A .LE. R .LE. B.
! A MUST BE LESS THAN B AND A MUST BE
! BE NON-NEGATIVE.
!
! M
! THE NUMBER OF GRID POINTS IN THE INTERVAL
! (A,B). THE GRID POINTS IN THE R-DIRECTION
! R-DIRECTION ARE GIVEN BY
! R(I) = A + (I-0.5)DR FOR I=1,2,...,M
! WHERE DR =(B-A)/M.
! M MUST BE GREATER THAN 2.
!
! MBDCND
! INDICATES THE TYPE OF BOUNDARY CONDITIONS
! AT R = A AND R = B.
!
! = 1 IF THE SOLUTION IS SPECIFIED AT R = A
! (SEE NOTE BELOW) AND R = B.
!
! = 2 IF THE SOLUTION IS SPECIFIED AT R = A
! (SEE NOTE BELOW) AND THE DERIVATIVE
! OF THE SOLUTION WITH RESPECT TO R IS
! SPECIFIED AT R = B.
!
! = 3 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO R IS SPECIFIED AT
! R = A (SEE NOTE BELOW) AND R = B.
!
! = 4 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO R IS SPECIFIED AT
! R = A (SEE NOTE BELOW) AND THE
! SOLUTION IS SPECIFIED AT R = B.
!
! = 5 IF THE SOLUTION IS UNSPECIFIED AT
! R = A = 0 AND THE SOLUTION IS
! SPECIFIED AT R = B.
!
! = 6 IF THE SOLUTION IS UNSPECIFIED AT
! R = A = 0 AND THE DERIVATIVE OF THE
! SOLUTION WITH RESPECT TO R IS SPECIFIED
! AT R = B.
!
! NOTE:
! IF A = 0, DO NOT USE MBDCND = 1,2,3, OR 4,
! BUT INSTEAD USE MBDCND = 5 OR 6.
! THE RESULTING APPROXIMATION GIVES THE ONLY
! MEANINGFUL BOUNDARY CONDITION,
! I.E. DU/DR = 0.
! (SEE D. GREENSPAN, 'INTRODUCTORY NUMERICAL
! ANALYSIS OF ELLIPTIC BOUNDARY VALUE
! PROBLEMS,' HARPER AND ROW, 1965, CHAPTER 5.)
!
! BDA
! A ONE-DIMENSIONAL ARRAY OF LENGTH N THAT
! SPECIFIES THE BOUNDARY VALUES (IF ANY)
! OF THE SOLUTION AT R = A.
!
! WHEN MBDCND = 1 OR 2,
! BDA(J) = U(A,Z(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 3 OR 4,
! BDA(J) = (D/DR)U(A,Z(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 5 OR 6, BDA IS A DUMMY
! VARIABLE.
!
! BDB
! A ONE-DIMENSIONAL ARRAY OF LENGTH N THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT R = B.
!
! WHEN MBDCND = 1,4,OR 5,
! BDB(J) = U(B,Z(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 2,3, OR 6,
! BDB(J) = (D/DR)U(B,Z(J)) , J=1,2,...,N.
!
! C,D
! THE RANGE OF Z, I.E. C .LE. Z .LE. D.
! C MUST BE LESS THAN D.
!
! N
! THE NUMBER OF UNKNOWNS IN THE INTERVAL
! (C,D). THE UNKNOWNS IN THE Z-DIRECTION
! ARE GIVEN BY Z(J) = C + (J-0.5)DZ,
! J=1,2,...,N, WHERE DZ = (D-C)/N.
! N MUST BE GREATER THAN 2.
!
! NBDCND
! INDICATES THE TYPE OF BOUNDARY CONDITIONS
! AT Z = C AND Z = D.
!
! = 0 IF THE SOLUTION IS PERIODIC IN Z, I.E.
! U(I,J) = U(I,N+J).
!
! = 1 IF THE SOLUTION IS SPECIFIED AT Z = C
! AND Z = D.
!
! = 2 IF THE SOLUTION IS SPECIFIED AT Z = C
! AND THE DERIVATIVE OF THE SOLUTION WITH
! RESPECT TO Z IS SPECIFIED AT Z = D.
!
! = 3 IF THE DERIVATIVE OF THE SOLUTION WITH
! RESPECT TO Z IS SPECIFIED AT Z = C
! AND Z = D.
!
! = 4 IF THE DERIVATIVE OF THE SOLUTION WITH
! RESPECT TO Z IS SPECIFIED AT Z = C AND
! THE SOLUTION IS SPECIFIED AT Z = D.
!
! BDC
! A ONE DIMENSIONAL ARRAY OF LENGTH M THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT Z = C.
!
! WHEN NBDCND = 1 OR 2,
! BDC(I) = U(R(I),C) , I=1,2,...,M.
!
! WHEN NBDCND = 3 OR 4,
! BDC(I) = (D/DZ)U(R(I),C), I=1,2,...,M.
!
! WHEN NBDCND = 0, BDC IS A DUMMY VARIABLE.
!
! BDD
! A ONE-DIMENSIONAL ARRAY OF LENGTH M THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT Z = D.
!
! WHEN NBDCND = 1 OR 4,
! BDD(I) = U(R(I),D) , I=1,2,...,M.
!
! WHEN NBDCND = 2 OR 3,
! BDD(I) = (D/DZ)U(R(I),D) , I=1,2,...,M.
!
! WHEN NBDCND = 0, BDD IS A DUMMY VARIABLE.
!
! ELMBDA
! THE CONSTANT LAMBDA IN THE MODIFIED
! HELMHOLTZ EQUATION. IF LAMBDA IS GREATER
! THAN 0, A SOLUTION MAY NOT EXIST.
! HOWEVER, HSTCYL WILL ATTEMPT TO FIND A
! SOLUTION. LAMBDA MUST BE ZERO WHEN
! MBDCND = 5 OR 6.
!
! F
! A TWO-DIMENSIONAL ARRAY THAT SPECIFIES
! THE VALUES OF THE RIGHT SIDE OF THE
! MODIFIED HELMHOLTZ EQUATION.
! FOR I=1,2,...,M AND J=1,2,...,N
! F(I,J) = F(R(I),Z(J)) .
! F MUST BE DIMENSIONED AT LEAST M X N.
!
! IDIMF
! THE ROW (OR FIRST) DIMENSION OF THE ARRAY
! F AS IT APPEARS IN THE PROGRAM CALLING
! HSTCYL. THIS PARAMETER IS USED TO SPECIFY
! THE VARIABLE DIMENSION OF F. IDIMF MUST
! BE AT LEAST M.
!
! ON OUTPUT
!
! F
! CONTAINS THE SOLUTION U(I,J) OF THE FINITE
! DIFFERENCE APPROXIMATION FOR THE GRID POINT
! (R(I),Z(J)) FOR I=1,2,...,M, J=1,2,...,N.
!
! PERTRB
! IF A COMBINATION OF PERIODIC, DERIVATIVE,
! OR UNSPECIFIED BOUNDARY CONDITIONS IS
! SPECIFIED FOR A POISSON EQUATION
! (LAMBDA = 0), A SOLUTION MAY NOT EXIST.
! PERTRB IS A CONSTANT, CALCULATED AND
! SUBTRACTED FROM F, WHICH ENSURES THAT A
! SOLUTION EXISTS. HSTCYL THEN COMPUTES
! THIS SOLUTION, WHICH IS A LEAST SQUARES
! SOLUTION TO THE ORIGINAL APPROXIMATION.
! THIS SOLUTION PLUS ANY CONSTANT IS ALSO
! A SOLUTION; HENCE, THE SOLUTION IS NOT
! UNIQUE. THE VALUE OF PERTRB SHOULD BE
! SMALL COMPARED TO THE RIGHT SIDE F.
! OTHERWISE, A SOLUTION IS OBTAINED TO AN
! ESSENTIALLY DIFFERENT PROBLEM.
! THIS COMPARISON SHOULD ALWAYS BE MADE TO
! INSURE THAT A MEANINGFUL SOLUTION HAS BEEN
! OBTAINED.
!
! IERROR
! AN ERROR FLAG THAT INDICATES INVALID INPUT
! PARAMETERS. EXCEPT TO NUMBERS 0 AND 11,
! A SOLUTION IS NOT ATTEMPTED.
!
! = 0 NO ERROR
!
! = 1 A .LT. 0
!
! = 2 A .GE. B
!
! = 3 MBDCND .LT. 1 OR MBDCND .GT. 6
!
! = 4 C .GE. D
!
! = 5 N .LE. 2
!
! = 6 NBDCND .LT. 0 OR NBDCND .GT. 4
!
! = 7 A = 0 AND MBDCND = 1,2,3, OR 4
!
! = 8 A .GT. 0 AND MBDCND .GE. 5
!
! = 9 M .LE. 2
!
! = 10 IDIMF .LT. M
!
! = 11 LAMBDA .GT. 0
!
! = 12 A=0, MBDCND .GE. 5, ELMBDA .NE. 0
!
! SINCE THIS IS THE ONLY MEANS OF INDICATING
! A POSSIBLY INCORRECT CALL TO HSTCYL, THE
! USER SHOULD TEST IERROR AFTER THE CALL.
!
! = 20 If the dynamic allocation of real and
! complex work space required for solution
! fails (for example if N,M are too large
! for your computer)
! I/O NONE
!
! PRECISION SINGLE
!
! REQUIRED LIBRARY fish.f,comf.f,genbun.f,gnbnaux.f,poistg.f
! FILES
!
! LANGUAGE FORTRAN 90
!
! HISTORY WRITTEN BY ROLAND SWEET AT NCAR IN 1977.
! RELEASED ON NCAR'S PUBLIC SOFTWARE LIBRARIES
! IN JANUARY 1980.
! Revised in June 2004 by John Adams using
! Fortran 90 dynamically allocated work space.
!
! PORTABILITY FORTRAN 90
!
! ALGORITHM THIS SUBROUTINE DEFINES THE FINITE-DIFFERENCE
! EQUATIONS, INCORPORATES BOUNDARY DATA, ADJUSTS
! THE RIGHT SIDE WHEN THE SYSTEM IS SINGULAR AND
! CALLS EITHER POISTG OR GENBUN WHICH SOLVES THE
! LINEAR SYSTEM OF EQUATIONS.
!
! TIMING FOR LARGE M AND N, THE OPERATION COUNT
! IS ROUGHLY PROPORTIONAL TO M*N*LOG2(N).
!
! ACCURACY THE SOLUTION PROCESS RESULTS IN A LOSS
! OF NO MORE THAN FOUR SIGNIFICANT DIGITS
! FOR N AND M AS LARGE AS 64.
! MORE DETAILED INFORMATION ABOUT ACCURACY
! CAN BE FOUND IN THE DOCUMENTATION FOR
! SUBROUTINE POISTG WHICH IS THE ROUTINE THAT
! ACTUALLY SOLVES THE FINITE DIFFERENCE
! EQUATIONS.
!
! REFERENCES U. SCHUMANN AND R. SWEET, "A DIRECT METHOD FOR
! THE SOLUTION OF POISSON'S EQUATION WITH NEUMANN
! BOUNDARY CONDITIONS ON A STAGGERED GRID OF
! ARBITRARY SIZE," J. COMP. PHYS. 20(1976),
! PP. 171-182.
!***********************************************************************
SUBROUTINE HSTCYL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, &
NBDCND, vecBDC, vecBDD, ELMBDA, matF, IDIMF, &
PERTRB, IERROR)
USE fish
implicit none
DOUBLE PRECISION, PARAMETER :: ZERO = 0.0D0, HALF = 0.5D0, &
ONE = 1.0D0, TWO = 2.0D0, &
FOUR = 4.0D0
!-----------------------------------------------
! D u m m y A r g u m e n t s
!-----------------------------------------------
INTEGER, INTENT(IN) :: M, MBDCND, N, NBDCND, IDIMF
INTEGER, INTENT(OUT) :: IERROR
DOUBLE PRECISION, INTENT(IN) :: A, B, C, D, ELMBDA
DOUBLE PRECISION, INTENT(OUT) :: PERTRB
DOUBLE PRECISION, DIMENSION(:), INTENT(IN) :: vecBDA, vecBDB, vecBDC, &
vecBDD
DOUBLE PRECISION, DIMENSION(IDIMF,N), INTENT(INOUT) :: matF
!-----------------------------------------------
! Allocatable arrays
!-----------------------------------------------
DOUBLE PRECISION,DIMENSION(:),ALLOCATABLE :: work
!-----------------------------------------------
! L o c a l V a r i a b l e s
!-----------------------------------------------
INTEGER :: irwk, istatus
!-----------------------------------------------
! JANNIS: add interface
interface
SUBROUTINE HSTCYLL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, matF, IDIMF, PERTRB, IERROR, W)
INTEGER, INTENT(IN) :: M, MBDCND, N, NBDCND, IDIMF
INTEGER, INTENT(OUT) :: IERROR
DOUBLE PRECISION, INTENT(IN) :: A, B, C, D, ELMBDA
DOUBLE PRECISION, INTENT(OUT) :: PERTRB
DOUBLE PRECISION, DIMENSION(M), INTENT(IN) :: vecBDA, vecBDB,vecBDC, &
vecBDD
DOUBLE PRECISION, DIMENSION(IDIMF,N), INTENT(INOUT) :: matF
DOUBLE PRECISION, DIMENSION(:), INTENT(OUT) :: W
end subroutine hstcyll
end interface
IERROR = 0
IF (A < ZERO) IERROR = 1
IF (A >= B) IERROR = 2
IF (MBDCND<=0 .OR. MBDCND>=7) IERROR = 3
IF (C >= D) IERROR = 4
IF (N <= 2) IERROR = 5
IF (NBDCND<0 .OR. NBDCND>=5) IERROR = 6
IF (A==ZERO .AND. MBDCND/=5 .AND. MBDCND/=6) IERROR = 7
IF (A>ZERO .AND. MBDCND>=5) IERROR = 8
IF (IDIMF < M) IERROR = 10
IF (M <= 2) IERROR = 9
IF (A==ZERO .AND. MBDCND>=5 .AND. ELMBDA/=ZERO) IERROR = 12
IF (IERROR /= 0) RETURN
! allocate real work space
! compute and allocate required real work space
CALL GEN_SPACE (N, M, IRWK)
IRWK = IRWK + 3*M
allocate(work(irwK),STAT=istatus)
!@! write(*,*) 'HSTCYL: allocate work(irwk); irwk=',irwk
! return if allocation failed (e.g., if n,m are too large)
IF (istatus > 0) THEN
write(*,*) 'HSTCYL: error allocate work(irwk); irwk=',irwk
RETURN
END IF
! check that allocation was successful
call HSTCYLL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, matF, IDIMF, PERTRB, IERROR, work)
! release allocated work space
!@! write(*,*) 'HSTCYL: deallocate work(irwk); irwk=',irwk
deallocate(work,STAT=istatus)
IF (istatus > 0) THEN
write(*,*) 'HSTCYL: error deallocate work'
RETURN
END IF
!
! RETURN
END SUBROUTINE HSTCYL
SUBROUTINE HSTCYLL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, matF, IDIMF, PERTRB, IERROR, W)
! USE poisson
! USE genbunal
implicit none
DOUBLE PRECISION, PARAMETER :: ZERO = 0.0D0, HALF = 0.5D0, &
ONE = 1.0D0, TWO = 2.0D0, &
FOUR = 4.0D0
!-----------------------------------------------
! D u m m y A r g u m e n t s
!-----------------------------------------------
INTEGER, INTENT(IN) :: M, MBDCND, N, NBDCND, IDIMF
INTEGER, INTENT(OUT) :: IERROR
DOUBLE PRECISION, INTENT(IN) :: A, B, C, D, ELMBDA
DOUBLE PRECISION, INTENT(OUT) :: PERTRB
DOUBLE PRECISION, DIMENSION(M), INTENT(IN) :: vecBDA, vecBDB,vecBDC, &
vecBDD
DOUBLE PRECISION, DIMENSION(IDIMF,N), INTENT(INOUT) :: matF
DOUBLE PRECISION, DIMENSION(:), INTENT(OUT) :: W
!-----------------------------------------------
! L o c a l V a r i a b l e s
!-----------------------------------------------
INTEGER :: NP, IWB, IWC, IWR, I, J, K, LP, IERR1
DOUBLE PRECISION :: DELTAR, DLRSQ, DELTHT, DLTHSQ, A1
!-----------------------------------------------
DELTAR = (B - A)/DBLE(M)
DLRSQ = DELTAR**2
DELTHT = (D - C)/DBLE(N)
DLTHSQ = DELTHT**2
NP = NBDCND + 1
!
! DEFINE A,B,C COEFFICIENTS IN W-ARRAY.
!
IWB = M
IWC = IWB + M
IWR = IWC + M
DO I = 1, M
J = IWR + I
W(J) = A + (DBLE(I) - HALF)*DELTAR
W(I) = (A + DBLE(I - 1)*DELTAR)/(DLRSQ*W(J))
K = IWC + I
W(K) = (A + DBLE(I)*DELTAR)/(DLRSQ*W(J))
K = IWB + I
W(K) = ELMBDA/W(J)**2 - TWO/DLRSQ
END DO
!
! ENTER BOUNDARY DATA FOR R-BOUNDARIES.
!
GO TO (102,102,104,104,106,106) MBDCND
102 CONTINUE
A1 = TWO*W(1)
W(IWB+1) = W(IWB+1) - W(1)
matF(1,:N) = matF(1,:N) - A1*vecBDA(:N)
GO TO 106
104 CONTINUE
A1 = DELTAR*W(1)
W(IWB+1) = W(IWB+1) + W(1)
matF(1,:N) = matF(1,:N) + A1*vecBDA(:N)
106 CONTINUE
GO TO (107,109,109,107,107,109) MBDCND
107 CONTINUE
W(IWC) = W(IWC) - W(IWR)
A1 = TWO*W(IWR)
matF(M,:N) = matF(M,:N) - A1*vecBDB(:N)
GO TO 111
109 CONTINUE
W(IWC) = W(IWC) + W(IWR)
A1 = DELTAR*W(IWR)
matF(M,:N) = matF(M,:N) - A1*vecBDB(:N)
!
! ENTER BOUNDARY DATA FOR THETA-BOUNDARIES.
!
111 CONTINUE
A1 = TWO/DLTHSQ
GO TO (121,112,112,114,114) NP
112 CONTINUE
matF(:M,1) = matF(:M,1) - A1*vecBDC(:M)
GO TO 116
114 CONTINUE
A1 = ONE/DELTHT
matF(:M,1) = matF(:M,1) + A1*vecBDC(:M)
116 CONTINUE
A1 = TWO/DLTHSQ
GO TO (121,117,119,119,117) NP
117 CONTINUE
matF(:M,N) = matF(:M,N) - A1*vecBDD(:M)
GO TO 121
119 CONTINUE
A1 = ONE/DELTHT
matF(:M,N) = matF(:M,N) - A1*vecBDD(:M)
121 CONTINUE
PERTRB = ZERO
IF (ELMBDA >= ZERO) THEN
IF (ELMBDA /= ZERO) THEN
IERROR = 11
ELSE
GO TO (130,130,124,130,130,124) MBDCND
124 CONTINUE
GO TO (125,130,130,125,130) NP
125 CONTINUE
DO I = 1, M
A1 = ZERO
A1 = SUM(matF(I,:N))
J = IWR + I
PERTRB = PERTRB + A1*W(J)
END DO
PERTRB = PERTRB/(DBLE(M*N)*HALF*(A + B))
matF(:M,:N) = matF(:M,:N) - PERTRB
ENDIF
ENDIF
130 CONTINUE
W(:M) = W(:M)*DLTHSQ
W(IWC+1:M+IWC) = W(IWC+1:M+IWC)*DLTHSQ
W(IWB+1:M+IWB) = W(IWB+1:M+IWB)*DLTHSQ
matF(:M,:N) = matF(:M,:N)*DLTHSQ
LP = NBDCND
W(1) = ZERO
W(IWR) = ZERO
!
! SOLVE THE SYSTEM OF EQUATIONS.
!
IERR1 = 0
IF (NBDCND /= 0) THEN
CALL POISTGG (LP, N, 1, M, W(1:M), W(IWB+1:IWB+M), W(IWC+1:IWC+M), &
IDIMF, matF, IERR1, W(IWR+1:), SIZE(W)-IWR)
ELSE
CALL GENBUNN (LP, N, 1, M, W(1:M), W(IWB+1:IWB+M), W(IWC+1:IWC+M), &
IDIMF, matF, IERR1, W(IWR+1:), SIZE(W)-IWR)
ENDIF
! RETURN
!
! REVISION HISTORY---
!
! SEPTEMBER 1973 VERSION 1
! APRIL 1976 VERSION 2
! JANUARY 1978 VERSION 3
! DECEMBER 1979 VERSION 3.1
! FEBRUARY 1985 DOCUMENTATION UPGRADE
! NOVEMBER 1988 VERSION 3.2, FORTRAN 77 CHANGES
! June 2004 Version 5.0, Fortran 90 changes
!-----------------------------------------------------------------------
END SUBROUTINE HSTCYLL
!
! file mhstcyl.f
!
! . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
! . .
! . copyright (c) 2004 by UCAR .
! . .
! . UNIVERSITY CORPORATION for ATMOSPHERIC RESEARCH .
! . .
! . all rights reserved .
! . .
! . .
! . FISHPACK version 5.0 .
! . .
! . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
!
! * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
! * *
! * F I S H P A C K *
! * *
! * *
! * A PACKAGE OF FORTRAN SUBPROGRAMS FOR THE SOLUTION OF *
! * *
! * SEPARABLE ELLIPTIC PARTIAL DIFFERENTIAL EQUATIONS *
! * *
! * (Version 5.0 , JUNE 2004) *
! * *
! * BY *
! * *
! * JOHN ADAMS, PAUL SWARZTRAUBER AND ROLAND SWEET *
! * *
! * OF *
! * *
! * THE NATIONAL CENTER FOR ATMOSPHERIC RESEARCH *
! * *
! * BOULDER, COLORADO (80307) U.S.A. *
! * *
! * WHICH IS SPONSORED BY *
! * *
! * THE NATIONAL SCIENCE FOUNDATION *
! * *
! * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
!
! SUBROUTINE MHSTCYL (A,B,M,MBDCND,BDA,BDB,C,D,N,NBDCND,BDC,BDD,
! + ELMBDA,ES,F,IDIMF,PERTRB,IERROR)
!
! DIMENSION OF BDA(N),BDB(N),BDC(M),BDD(M),F(IDIMF,N)
! ARGUMENTS
!
! LATEST REVISION June 2004
!
! PURPOSE SOLVES THE STANDARD FIVE-POINT FINITE
! DIFFERENCE APPROXIMATION ON A STAGGERED
! GRID TO THE MODIFIED HELMHOLTZ EQUATION
! IN CYLINDRICAL COORDINATES. THIS EQUATION
!
! (D2U/DR2) + (D/DZ)(DU/DZ)
!
! + LAMBDA*(1/R**2)*U + ES * U = F(R,Z)
!
! IS A TWO-DIMENSIONAL MODIFIED HELMHOLTZ
! EQUATION RESULTING FROM THE FOURIER TRANSFORM
! OF A THREE-DIMENSIONAL POISSON EQUATION.
!
! USAGE CALL MHSTCYL (A,B,M,MBDCND,BDA,BDB,C,D,N,
! NBDCND,BDC,BDD,ELMBDA,ES,F,IDIMF,
! PERTRB,IERROR)
!
! ARGUMENTS
! ON INPUT A,B
!
! THE RANGE OF R, I.E. A .LE. R .LE. B.
! A MUST BE LESS THAN B AND A MUST BE
! BE NON-NEGATIVE.
!
! M
! THE NUMBER OF GRID POINTS IN THE INTERVAL
! (A,B). THE GRID POINTS IN THE R-DIRECTION
! R-DIRECTION ARE GIVEN BY
! R(I) = A + (I-0.5)DR FOR I=1,2,...,M
! WHERE DR =(B-A)/M.
! M MUST BE GREATER THAN 2.
!
! MBDCND
! INDICATES THE TYPE OF BOUNDARY CONDITIONS
! AT R = A AND R = B.
!
! = 1 IF THE SOLUTION IS SPECIFIED AT R = A
! (SEE NOTE BELOW) AND R = B.
!
! = 2 IF THE SOLUTION IS SPECIFIED AT R = A
! (SEE NOTE BELOW) AND THE DERIVATIVE
! OF THE SOLUTION WITH RESPECT TO R IS
! SPECIFIED AT R = B.
!
! = 3 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO R IS SPECIFIED AT
! R = A (SEE NOTE BELOW) AND R = B.
!
! = 4 IF THE DERIVATIVE OF THE SOLUTION
! WITH RESPECT TO R IS SPECIFIED AT
! R = A (SEE NOTE BELOW) AND THE
! SOLUTION IS SPECIFIED AT R = B.
!
! = 5 IF THE SOLUTION IS UNSPECIFIED AT
! R = A = 0 AND THE SOLUTION IS
! SPECIFIED AT R = B.
!
! = 6 IF THE SOLUTION IS UNSPECIFIED AT
! R = A = 0 AND THE DERIVATIVE OF THE
! SOLUTION WITH RESPECT TO R IS SPECIFIED
! AT R = B.
!
! NOTE:
! IF A = 0, DO NOT USE MBDCND = 1,2,3, OR 4,
! BUT INSTEAD USE MBDCND = 5 OR 6.
! THE RESULTING APPROXIMATION GIVES THE ONLY
! MEANINGFUL BOUNDARY CONDITION,
! I.E. DU/DR = 0.
! (SEE D. GREENSPAN, 'INTRODUCTORY NUMERICAL
! ANALYSIS OF ELLIPTIC BOUNDARY VALUE
! PROBLEMS,' HARPER AND ROW, 1965, CHAPTER 5.)
!
! BDA
! A ONE-DIMENSIONAL ARRAY OF LENGTH N THAT
! SPECIFIES THE BOUNDARY VALUES (IF ANY)
! OF THE SOLUTION AT R = A.
!
! WHEN MBDCND = 1 OR 2,
! BDA(J) = U(A,Z(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 3 OR 4,
! BDA(J) = (D/DR)U(A,Z(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 5 OR 6, BDA IS A DUMMY
! VARIABLE.
!
! BDB
! A ONE-DIMENSIONAL ARRAY OF LENGTH N THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT R = B.
!
! WHEN MBDCND = 1,4,OR 5,
! BDB(J) = U(B,Z(J)) , J=1,2,...,N.
!
! WHEN MBDCND = 2,3, OR 6,
! BDB(J) = (D/DR)U(B,Z(J)) , J=1,2,...,N.
!
! C,D
! THE RANGE OF Z, I.E. C .LE. Z .LE. D.
! C MUST BE LESS THAN D.
!
! N
! THE NUMBER OF UNKNOWNS IN THE INTERVAL
! (C,D). THE UNKNOWNS IN THE Z-DIRECTION
! ARE GIVEN BY Z(J) = C + (J-0.5)DZ,
! J=1,2,...,N, WHERE DZ = (D-C)/N.
! N MUST BE GREATER THAN 2.
!
! NBDCND
! INDICATES THE TYPE OF BOUNDARY CONDITIONS
! AT Z = C AND Z = D.
!
! = 0 IF THE SOLUTION IS PERIODIC IN Z, I.E.
! U(I,J) = U(I,N+J).
!
! = 1 IF THE SOLUTION IS SPECIFIED AT Z = C
! AND Z = D.
!
! = 2 IF THE SOLUTION IS SPECIFIED AT Z = C
! AND THE DERIVATIVE OF THE SOLUTION WITH
! RESPECT TO Z IS SPECIFIED AT Z = D.
!
! = 3 IF THE DERIVATIVE OF THE SOLUTION WITH
! RESPECT TO Z IS SPECIFIED AT Z = C
! AND Z = D.
!
! = 4 IF THE DERIVATIVE OF THE SOLUTION WITH
! RESPECT TO Z IS SPECIFIED AT Z = C AND
! THE SOLUTION IS SPECIFIED AT Z = D.
!
! BDC
! A ONE DIMENSIONAL ARRAY OF LENGTH M THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT Z = C.
!
! WHEN NBDCND = 1 OR 2,
! BDC(I) = U(R(I),C) , I=1,2,...,M.
!
! WHEN NBDCND = 3 OR 4,
! BDC(I) = (D/DZ)U(R(I),C), I=1,2,...,M.
!
! WHEN NBDCND = 0, BDC IS A DUMMY VARIABLE.
!
! BDD
! A ONE-DIMENSIONAL ARRAY OF LENGTH M THAT
! SPECIFIES THE BOUNDARY VALUES OF THE
! SOLUTION AT Z = D.
!
! WHEN NBDCND = 1 OR 4,
! BDD(I) = U(R(I),D) , I=1,2,...,M.
!
! WHEN NBDCND = 2 OR 3,
! BDD(I) = (D/DZ)U(R(I),D) , I=1,2,...,M.
!
! WHEN NBDCND = 0, BDD IS A DUMMY VARIABLE.
!
! ELMBDA
! THE CONSTANT LAMBDA IN THE MODIFIED
! HELMHOLTZ EQUATION. IF LAMBDA IS GREATER
! THAN 0, A SOLUTION MAY NOT EXIST.
! HOWEVER, MHSTCYL WILL ATTEMPT TO FIND A
! SOLUTION. LAMBDA MUST BE ZERO WHEN
! MBDCND = 5 OR 6.
!
! F
! A TWO-DIMENSIONAL ARRAY THAT SPECIFIES
! THE VALUES OF THE RIGHT SIDE OF THE
! MODIFIED HELMHOLTZ EQUATION.
! FOR I=1,2,...,M AND J=1,2,...,N
! F(I,J) = F(R(I),Z(J)) .
! F MUST BE DIMENSIONED AT LEAST M X N.
!
! IDIMF
! THE ROW (OR FIRST) DIMENSION OF THE ARRAY
! F AS IT APPEARS IN THE PROGRAM CALLING
! MHSTCYL. THIS PARAMETER IS USED TO SPECIFY
! THE VARIABLE DIMENSION OF F. IDIMF MUST
! BE AT LEAST M.
!
! ON OUTPUT
!
! F
! CONTAINS THE SOLUTION U(I,J) OF THE FINITE
! DIFFERENCE APPROXIMATION FOR THE GRID POINT
! (R(I),Z(J)) FOR I=1,2,...,M, J=1,2,...,N.
!
! PERTRB
! IF A COMBINATION OF PERIODIC, DERIVATIVE,
! OR UNSPECIFIED BOUNDARY CONDITIONS IS
! SPECIFIED FOR A POISSON EQUATION
! (LAMBDA = 0), A SOLUTION MAY NOT EXIST.
! PERTRB IS A CONSTANT, CALCULATED AND
! SUBTRACTED FROM F, WHICH ENSURES THAT A
! SOLUTION EXISTS. MHSTCYL THEN COMPUTES
! THIS SOLUTION, WHICH IS A LEAST SQUARES
! SOLUTION TO THE ORIGINAL APPROXIMATION.
! THIS SOLUTION PLUS ANY CONSTANT IS ALSO
! A SOLUTION; HENCE, THE SOLUTION IS NOT
! UNIQUE. THE VALUE OF PERTRB SHOULD BE
! SMALL COMPARED TO THE RIGHT SIDE F.
! OTHERWISE, A SOLUTION IS OBTAINED TO AN
! ESSENTIALLY DIFFERENT PROBLEM.
! THIS COMPARISON SHOULD ALWAYS BE MADE TO
! INSURE THAT A MEANINGFUL SOLUTION HAS BEEN
! OBTAINED.
!
! IERROR
! AN ERROR FLAG THAT INDICATES INVALID INPUT
! PARAMETERS. EXCEPT TO NUMBERS 0 AND 11,
! A SOLUTION IS NOT ATTEMPTED.
!
! = 0 NO ERROR
!
! = 1 A .LT. 0
!
! = 2 A .GE. B
!
! = 3 MBDCND .LT. 1 OR MBDCND .GT. 6
!
! = 4 C .GE. D
!
! = 5 N .LE. 2
!
! = 6 NBDCND .LT. 0 OR NBDCND .GT. 4
!
! = 7 A = 0 AND MBDCND = 1,2,3, OR 4
!
! = 8 A .GT. 0 AND MBDCND .GE. 5
!
! = 9 M .LE. 2
!
! = 10 IDIMF .LT. M
!
! = 11 LAMBDA .GT. 0
!
! = 12 A=0, MBDCND .GE. 5, ELMBDA .NE. 0
!
! SINCE THIS IS THE ONLY MEANS OF INDICATING
! A POSSIBLY INCORRECT CALL TO MHSTCYL, THE
! USER SHOULD TEST IERROR AFTER THE CALL.
!
! = 20 If the dynamic allocation of real and
! complex work space required for solution
! fails (for example if N,M are too large
! for your computer)
! I/O NONE
!
! PRECISION SINGLE
!
! REQUIRED LIBRARY fish.f,comf.f,genbun.f,gnbnaux.f,poistg.f
! FILES
!
! LANGUAGE FORTRAN 90
!
! HISTORY WRITTEN BY ROLAND SWEET AT NCAR IN 1977.
! RELEASED ON NCAR'S PUBLIC SOFTWARE LIBRARIES
! IN JANUARY 1980.
! Revised in June 2004 by John Adams using
! Fortran 90 dynamically allocated work space.
!
! PORTABILITY FORTRAN 90
!
! ALGORITHM THIS SUBROUTINE DEFINES THE FINITE-DIFFERENCE
! EQUATIONS, INCORPORATES BOUNDARY DATA, ADJUSTS
! THE RIGHT SIDE WHEN THE SYSTEM IS SINGULAR AND
! CALLS EITHER POISTG OR GENBUN WHICH SOLVES THE
! LINEAR SYSTEM OF EQUATIONS.
!
! TIMING FOR LARGE M AND N, THE OPERATION COUNT
! IS ROUGHLY PROPORTIONAL TO M*N*LOG2(N).
!
! ACCURACY THE SOLUTION PROCESS RESULTS IN A LOSS
! OF NO MORE THAN FOUR SIGNIFICANT DIGITS
! FOR N AND M AS LARGE AS 64.
! MORE DETAILED INFORMATION ABOUT ACCURACY
! CAN BE FOUND IN THE DOCUMENTATION FOR
! SUBROUTINE POISTG WHICH IS THE ROUTINE THAT
! ACTUALLY SOLVES THE FINITE DIFFERENCE
! EQUATIONS.
!
! REFERENCES U. SCHUMANN AND R. SWEET, "A DIRECT METHOD FOR
! THE SOLUTION OF POISSON'S EQUATION WITH NEUMANN
! BOUNDARY CONDITIONS ON A STAGGERED GRID OF
! ARBITRARY SIZE," J. COMP. PHYS. 20(1976),
! PP. 171-182.
!***********************************************************************
SUBROUTINE MHSTCYL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, &
N, NBDCND, vecBDC, vecBDD, ELMBDA, ES, &
matF, IDIMF, PERTRB, IERROR)
USE fish
implicit none
DOUBLE PRECISION, PARAMETER :: ZERO = 0.0D0, HALF = 0.5D0, &
ONE = 1.0D0, TWO = 2.0D0, &
FOUR = 4.0D0
!-----------------------------------------------
! D u m m y A r g u m e n t s
!-----------------------------------------------
INTEGER, INTENT(IN) :: M, MBDCND, N, NBDCND, IDIMF
INTEGER, INTENT(OUT) :: IERROR
DOUBLE PRECISION, INTENT(IN) :: A, B, C, D, ELMBDA, ES
DOUBLE PRECISION, INTENT(OUT) :: PERTRB
DOUBLE PRECISION, DIMENSION(N), INTENT(IN) :: vecBDA, vecBDB
DOUBLE PRECISION, DIMENSION(M), INTENT(IN) :: vecBDC, vecBDD
DOUBLE PRECISION, DIMENSION(IDIMF,N), INTENT(OUT) :: matF
!-----------------------------------------------
! Allocatable arrays
!-----------------------------------------------
DOUBLE PRECISION,DIMENSION(:),ALLOCATABLE :: work
!-----------------------------------------------
! L o c a l V a r i a b l e s
!-----------------------------------------------
INTEGER :: irwk, istatus
!-----------------------------------------------
IERROR = 0
IF (A < ZERO) IERROR = 1
IF (A >= B) IERROR = 2
IF (MBDCND<=0 .OR. MBDCND>=7) IERROR = 3
IF (C >= D) IERROR = 4
IF (N <= 2) IERROR = 5
IF (NBDCND<0 .OR. NBDCND>=5) IERROR = 6
!Mod IF (A==ZERO .AND. MBDCND/=5 .AND. MBDCND/=6) IERROR = 7
IF (A>ZERO .AND. MBDCND>=5) IERROR = 8
IF (IDIMF < M) IERROR = 10
IF (M <= 2) IERROR = 9
!Mod IF (A==ZERO .AND. MBDCND>=5 .AND. ELMBDA/=ZERO) IERROR = 12
IF (IERROR /= 0) RETURN
! allocate real work space
! compute and allocate required real work space
CALL GEN_SPACE (N, M, IRWK)
IRWK = IRWK + 3*M
!@! write(*,*) 'MHSTCYL: allocate work(irwk); irwk=',irwk
allocate(work(irwk),STAT=istatus)
! return if allocation failed (e.g., if n,m are too large)
IF (istatus > 0) THEN
write(*,*) 'HSTCRT: error allocate work(irwk); irwk=',irwk
RETURN
END IF
call MHSTCYLL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, ES, matF, IDIMF, PERTRB, &
IERROR, work, IRWK )
! release allocated work space
!@! write(*,*) 'MHSTCYL: deallocate work(irwk); irwk=',irwk
deallocate(work,STAT=istatus)
IF (istatus > 0) THEN
write(*,*) 'MHSTCYL: error deallocate work'
RETURN
END IF
!
END SUBROUTINE MHSTCYL
SUBROUTINE MHSTCYLL(A, B, M, MBDCND, vecBDA, vecBDB, C, D, N, NBDCND, &
vecBDC, vecBDD, ELMBDA, ES, matF, IDIMF, &
PERTRB, IERROR, W, IW)
! USE genbunal
! USE poisson
implicit none
DOUBLE PRECISION, PARAMETER :: ZERO = 0.0D0, HALF = 0.5D0, &
ONE = 1.0D0, TWO = 2.0D0, &
FOUR = 4.0D0
!-----------------------------------------------
! D u m m y A r g u m e n t s
!-----------------------------------------------
INTEGER, INTENT(IN) :: M, MBDCND, N, NBDCND, IDIMF, IW
INTEGER, INTENT(OUT) :: IERROR
DOUBLE PRECISION, INTENT(IN) :: A, B, C, D, ELMBDA, ES
DOUBLE PRECISION, INTENT(OUT) :: PERTRB
DOUBLE PRECISION, DIMENSION(N), INTENT(IN) :: vecBDA, vecBDB
DOUBLE PRECISION, DIMENSION(M), INTENT(IN) :: vecBDC, vecBDD
DOUBLE PRECISION, DIMENSION(IDIMF,N), INTENT(OUT) :: matF
DOUBLE PRECISION, DIMENSION(IW), INTENT(INOUT) :: W
!-----------------------------------------------
! L o c a l V a r i a b l e s
!-----------------------------------------------
INTEGER :: NP, IWB, IWC, IWR, I, J, K, LP, IERR1
DOUBLE PRECISION :: DELTAR, DLRSQ, DELTHT, DLTHSQ, A1
!-----------------------------------------------
DELTAR = (B - A)/DBLE(M)
DLRSQ = DELTAR**2
DELTHT = (D - C)/DBLE(N)
DLTHSQ = DELTHT**2
NP = NBDCND + 1
!
! DEFINE A,B,C COEFFICIENTS IN W-ARRAY.
!
IWB = M
IWC = IWB + M
IWR = IWC + M
DO I = 1, M
J = IWR + I
W(J) = A + (DBLE(I) - HALF)*DELTAR
W(I) = (W(J) - HALF * DELTAR)/(DLRSQ*W(J))
K = IWC + I
W(K) = (W(J) + HALF * DELTAR)/(DLRSQ*W(J))
K = IWB + I
W(K) = ELMBDA/W(J)**2 + ES - TWO/DLRSQ
END DO
!
! ENTER BOUNDARY DATA FOR R-BOUNDARIES.
!
GO TO (102,102,104,104,106,106) MBDCND
102 CONTINUE
A1 = TWO*W(1)
W(IWB+1) = W(IWB+1) - W(1)
matF(1,:N) = matF(1,:N) - A1*vecBDA(:N)
GO TO 106
104 CONTINUE
A1 = DELTAR*W(1)
W(IWB+1) = W(IWB+1) + W(1)
matF(1,:N) = matF(1,:N) + A1*vecBDA(:N)
106 CONTINUE
GO TO (107,109,109,107,107,109) MBDCND
107 CONTINUE
W(IWC) = W(IWC) - W(IWR)
A1 = TWO*W(IWR)
matF(M,:N) = matF(M,:N) - A1*vecBDB(:N)
GO TO 111
109 CONTINUE
W(IWC) = W(IWC) + W(IWR)
A1 = DELTAR*W(IWR)
matF(M,:N) = matF(M,:N) - A1*vecBDB(:N)
!
! ENTER BOUNDARY DATA FOR THETA-BOUNDARIES.
!
111 CONTINUE
A1 = TWO/DLTHSQ
GO TO (121,112,112,114,114) NP
112 CONTINUE
matF(:M,1) = matF(:M,1) - A1*vecBDC(:M)
GO TO 116
114 CONTINUE
A1 = ONE/DELTHT
matF(:M,1) = matF(:M,1) + A1*vecBDC(:M)
116 CONTINUE
A1 = TWO/DLTHSQ
GO TO (121,117,119,119,117) NP
117 CONTINUE
matF(:M,N) = matF(:M,N) - A1*vecBDD(:M)
GO TO 121
119 CONTINUE
A1 = ONE/DELTHT
matF(:M,N) = matF(:M,N) - A1*vecBDD(:M)
121 CONTINUE
PERTRB = ZERO
IF (ELMBDA >= ZERO) THEN
IF (ELMBDA /= ZERO) THEN
IERROR = 11
ELSE
GO TO (130,130,124,130,130,124) MBDCND
124 CONTINUE
GO TO (125,130,130,125,130) NP
125 CONTINUE
DO I = 1, M
A1 = ZERO
A1 = SUM(matF(I,:N))
J = IWR + I
PERTRB = PERTRB + A1*W(J)
END DO
PERTRB = PERTRB/(DBLE(M*N)*HALF*(A + B))
matF(:M,:N) = matF(:M,:N) - PERTRB
ENDIF
ENDIF
130 CONTINUE
W(:M) = W(:M)*DLTHSQ
W(IWC+1:M+IWC) = W(IWC+1:M+IWC)*DLTHSQ
W(IWB+1:M+IWB) = W(IWB+1:M+IWB)*DLTHSQ
matF(:M,:N) = matF(:M,:N)*DLTHSQ
LP = NBDCND
W(1) = ZERO
W(IWR) = ZERO
!
! SOLVE THE SYSTEM OF EQUATIONS.
!
IERR1 = 0
IF (NBDCND /= 0) THEN
CALL POISTGG (LP, N, 1, M, W, W(IWB+1:IWB+M), W(IWC+1:IWC+M), &
IDIMF, matF,IERR1, W(IWR+1:), size(W)-IWR)
ELSE
CALL GENBUNN (LP, N, 1, M, W, W(IWB+1:IWB+M), W(IWC+1:IWC+M), &
IDIMF, matF,IERR1, W(IWR+1:), size(W)-IWR)
ENDIF
!
! REVISION HISTORY---
!
! SEPTEMBER 1973 VERSION 1
! APRIL 1976 VERSION 2
! JANUARY 1978 VERSION 3
! DECEMBER 1979 VERSION 3.1
! FEBRUARY 1985 DOCUMENTATION UPGRADE
! NOVEMBER 1988 VERSION 3.2, FORTRAN 77 CHANGES
! June 2004 Version 5.0, Fortran 90 changes
! February 2009 Modified version of HSTCYL
!-----------------------------------------------------------------------
END SUBROUTINE MHSTCYLL
|